package gw.financials
uses java.util.Collection
uses java.util.List

class LegacyTransactionReducer<A> implements TransactionReducer<A> {

  static var _reductionCount : int = 0
  public static property get ReductionCount() : int {  //count total times reduce is called
    return _reductionCount
  }

  var _orderingFunction : block (txns : Collection<WrappedProratable<A>>) : WrappedProratable<A>
  var _transactions : List<WrappedProratable<A>>
  var _defaultProrater : Prorater

  construct(prorater : Prorater, orderingFunction(txns : Collection<WrappedProratable<A>>) : WrappedProratable<A>) {
    _defaultProrater = prorater
    _orderingFunction = orderingFunction
    _transactions = {}
  }

  override function add( t: WrappedProratable<A> ) : TransactionReducer<A> {
    _transactions.add(t)
    return this
  }

  override function reduce() : List<WrappedProratable<A>> {
    _reductionCount = _reductionCount + 1
    var result : List<WrappedProratable<A>> = {}
    var segmenter = new DateRangeSegmenter<WrappedProratable<A>>()
    for (t in _transactions) {
      segmenter.add( t.Start, t.End, t )  
    }

    segmenter.segment( \ start, end, txns -> {
      var elements = txns.map( \ t -> {
        var _prorater = t.getProrater(_defaultProrater)
        return _prorater.prorate( t.Start, t.End, start, end, t.Amount ) 
      })
      if (elements.Empty) {
        return
      }
      var sum = elements.sumWithAtLeastOneNonNullCurrency()
      if (not sum.IsZero) {
        var firstTransaction = _orderingFunction(txns)
        result.add(firstTransaction.subPeriod( start, end, sum))  
      }
    })
    
    return result
  }
}