package gw.document;

uses gw.plugin.document.IDocumentTemplateDescriptor

/**
 * Base implementation of some APIs of {@link DocumentApplicationContext}
 */
public abstract class BaseDocumentApplicationContext implements DocumentApplicationContext {
  private var _templateResetSinceLastChecked : boolean
  private var _documentCreationReadOnly : boolean
  private var _documentCreationResetState : DocumentCreationResetState

  public construct() {
  }

  override public function createDocumentCreationInfo() : DocumentCreationInfo {
      return createDocumentCreationInfo(null);
  }

  override public function resetTemplateBasedInfo(documentCreationInfo : DocumentCreationInfo,
                                                  documentTemplateDescriptor : IDocumentTemplateDescriptor) {
    _templateResetSinceLastChecked = true
    documentCreationInfo.DocumentTemplateDescriptor = documentTemplateDescriptor
    documentCreationInfo.File = null // releases resources for current WebFile, if any
    documentCreationInfo.Document.Name = documentTemplateDescriptor.getName(documentTemplateDescriptor.Language)
    documentCreationInfo.Document.Description = documentTemplateDescriptor.getDescription(documentTemplateDescriptor.Language)
    documentCreationInfo.Document.Type = DocumentType.get(documentCreationInfo.DocumentTemplateDescriptor.TemplateType)
    documentCreationInfo.Document.SecurityType =
        DocumentSecurityType.get(documentCreationInfo.DocumentTemplateDescriptor.DefaultSecurityType)
    documentCreationInfo.Document.Section =
        DocumentSection.get(documentCreationInfo.DocumentTemplateDescriptor.getMetadataPropertyValue("section") as String)
    documentCreationInfo.Document.MimeType = documentCreationInfo.DocumentTemplateDescriptor.MimeType
    if (documentCreationInfo.Document.Status == null) {
      documentCreationInfo.Document.Status = TC_DRAFT
    }
  }

  override public property get TemplateResetSinceSetLastChecked() : boolean {
    var rtn = _templateResetSinceLastChecked
    _templateResetSinceLastChecked = false
    return rtn
  }

  override public property get DocumentCreationReadOnly() : boolean {
    return _documentCreationReadOnly
  }

  override public property set DocumentCreationReadOnly(documentCreationReadOnly : boolean) {
    _documentCreationReadOnly = documentCreationReadOnly
  }

  override public property get DocumentCreationResetState() : DocumentCreationResetState {
    return _documentCreationResetState
  }

  override public property set DocumentCreationResetState(documentCreationResetState : DocumentCreationResetState) {
    _documentCreationResetState = documentCreationResetState
  }
}